
Library for dealing with data structures

	Installation
	Usage
	Types
	Construct definition
	Errors while making structures


Installation
	Add construct to your list of dependencies in mix.exs:

def deps do
  [{:construct, "~> 2.0"}]
end
	Ensure construct is started before your application:

def application do
  [applications: [:construct]]
end
Usage
Suppose you have some user input from several sources (DB, HTTP request, WebSocket), and you will need to process that data into something type-validated, like User entity. With this library you can define a type-validated structure for this entity:
defmodule User do
  use Construct do
    field :name
    field :age, :integer
  end
end
And use it to cast your data into something identical, to prevent type coercion in different places of your code. Like this:
iex> User.make(%{"name" => "John Doe", "age" => "37"})
{:ok, %User{age: 37, name: "John Doe"}}
Pretty neat, yeah? But what if you need more complex type? We have a solution!
defmodule Answer do
  @behaviour Construct.Type

  def cast("yes"), do: {:ok, true}
  def cast("no"), do: {:ok, false}
  def cast(_), do: {:error, :invalid_answer}
end
And use it in your structure like this:
defmodule Quiz do
  use Construct do
    field :user_id, :integer
    field :answers, {:array, Answer}
  end
end
iex> Quiz.make(%{user_id: 42, answers: ["yes", "no", "no", "yes"]})
{:ok, %Quiz{answers: [true, false, false, true], user_id: 42}}
What if we need to parse 'optimized' query string from URL, like list of user ids separated by a comma? Do we need to create a custom type for each boxed type?

No! Just use type composition feature:
defmodule CommaList do
  @behaviour Construct.Type

  def cast(""), do: {:ok, []}
  def cast(v) when is_binary(v), do: {:ok, String.split(v, ",")}
  def cast(v) when is_list(v), do: {:ok, v}
  def cast(_), do: :error
end

defmodule SearchFilterRequest do
  use Construct do
    field :user_ids, [CommaList, {:array, :integer}], default: []
  end
end
(Use CommaList type from construct_types package).
iex> SearchFilterRequest.make(%{"user_ids" => "1,2,42"})
{:ok, %SearchFilterRequest{user_ids: [1, 2, 42]}}
Also we have default option in our user_ids field:
iex> SearchFilterRequest.make(%{})
{:ok, %SearchFilterRequest{user_ids: []}}
What if I have a lot of identical code?

You can use already defined structures as types:
defmodule Comment do
  use Construct do
    field :text
  end
end

defmodule Post do
  use Construct do
    field :title
    field :comments, {:array, Comment}
  end
end

iex> Post.make(%{title: "Some article", comments: [%{"text" => "cool!"}, %{text: "awesome!!!"}]})
{:ok, %Post{comments: [%Comment{text: "cool!"}, %Comment{text: "awesome!!!"}], title: "Some article"}}
And include repeated fields in structures:
defmodule PK do
  use Construct do
    field :primary_key, :integer
  end
end

defmodule Timestamps do
  use Construct do
    field :created_at, :utc_datetime, default: &DateTime.utc_now/0
    field :updated_at, :utc_datetime, default: nil
  end
end

defmodule User do
  use Construct do
    include PK
    include Timestamps

    field :name
  end
end

iex> User.make(%{name: "John Doe", primary_key: 42})
{:ok,
 %User{created_at: #DateTime<2018-10-14 20:43:06.595119Z>, name: "John Doe",
  primary_key: 42, updated_at: nil}}

iex> User.make(%{name: "John Doe", created_at: "2015-01-23 23:50:07", primary_key: 42})
{:ok,
 %User{created_at: #DateTime<2015-01-23 23:50:07Z>, name: "John Doe",
  primary_key: 42, updated_at: nil}}
What if I don't want to define module to make a nested field?

field macro can do it for you:
defmodule User do
  use Construct do
    field :name do
      field :first
      field :last, :string, default: nil
    end
  end
end

iex> User.make(name: %{first: "John"})
{:ok, %User{name: %User.Name{first: "John", last: nil}}}
Construct tries to fit in Elixir as much as it possible:
defmodule ComplexDefaults do
  use Construct do
    field :required

    field :nested do
      field :key, :string, default: "nesting 1"

      field :nested do
        field :key, :string, default: "nesting 2"
      end
    end
  end
end

iex> %ComplexDefaults{}
** (ArgumentError) the following keys must also be given when building struct ComplexDefaults: [:required]
    expanding struct: ComplexDefaults.__struct__/1

iex> %ComplexDefaults{required: 1}
%ComplexDefaults{
  nested: %ComplexDefaults.Nested{
    key: "nesting 1",
    nested: %ComplexDefaults.Nested.Nested{key: "nesting 2"}
  },
  required: 1
}
What if I want to use union types?

Use custom types:
defmodule User do
  use Construct do
    field :id, :integer
    field :name
    field :age, :integer
  end
end

defmodule Bot do
  use Construct do
    field :id, :integer
    field :name
    field :version
  end
end

defmodule Author do
  @behaviour Construct.Type

  # here's the trick, just choose the type by yourself, based on keys or value in specific field.
  # but be careful, because there can be atoms and strings in keys!
  def cast(%{"age" => _} = v), do: User.make(v)
  def cast(%{"version" => _} = v), do: Bot.make(v)
  def cast(_), do: :error
end

defmodule Post do
  use Construct do
    field :author, Author
  end
end

iex> Post.make(%{"author" => %{}})
{:error, %{author: :invalid}}

iex> Post.make(%{"author" => %{"age" => "420"}})
{:error, %{author: %{id: :missing, name: :missing}}}

iex> Post.make(%{"author" => %{"id" => "42", "name" => "john doe", "age" => "420"}})
{:ok, %Post{author: %User{age: 420, id: 42, name: "john doe"}}}

iex> Post.make(%{"author" => %{"id" => "42", "name" => "john doe", "version" => "1.0.0"}})
{:ok, %Post{author: %Bot{id: 42, name: "john doe", version: "1.0.0"}}}
How can I serialize my structures with Jason?

Use @derive attribute and derive option for nested fields:
defmodule Server do
  @derive {Jason.Encoder, only: [:name, :operating_system]}

  use Construct do
    field :name
    field :password

    field :operating_system, derive: Jason.Encoder do
      field :name, :string
      field :arch, :string, default: "x86"
    end
  end
end

iex> {:ok, server} = Server.make(name: "example", password: "secret", operating_system: %{name: "MacOS"})
{:ok,
 %Server{
   name: "example",
   operating_system: %Server.OperatingSystem{arch: "x86", name: "MacOS"},
   password: "secret"
 }}

iex> Jason.encode!(server)
"{\"name\":\"example\",\"operating_system\":{\"arch\":\"x86\",\"name\":\"MacOS\"}}"
Types
Primitive types
	t():	integer
	float
	boolean
	string
	binary
	decimal
	utc_datetime
	naive_datetime
	date
	time
	any
	array
	map
	struct


	{:array, t()}
	{:map, t()}
	[t()]

Complex (custom) types
You can use Ecto custom types like Ecto.UUID or implement by yourself:
defmodule CustomType do
  @behaviour Construct.Type

  @spec cast(term) :: {:ok, term} | {:error, term} | :error
  def cast(value) do
    {:ok, value}
  end
end
Notice that cast/1 can return error with reason, this behaviour is supported only by Struct and you can't use types defined using Construct in Ecto schemas.
Construct definition
defmodule User do
  use Construct, struct_opts

  structure do
    include module_name

    field name
    field name, type
    field name, type, field_opts
  end
end
Where:
	use Construct, struct_opts where:	struct_opts — options passed to every make/2 and make!/2 calls as default options;


	include module_name where:	module_name — is struct module, that validates for existence in compile time;


	field name, type, field_opts where:	name — atom;
	type — primitive or custom type, that validates for existence in compile time;
	field_opts.



Errors while making structures
When you provide invalid data to your structures you can get tuple with errors as maps:
iex> Post.make
{:error, %{comments: :missing, title: :missing}}

iex> Post.make(%{comments: %{}, title: :test})
{:error, %{comments: :invalid, title: :invalid}}

iex> Post.make(%{comments: [%{}], title: "what the title?"})
{:error, %{comments: %{text: :missing}}}
Or receive an exception with invalid data:
iex> Post.make!
** (Construct.MakeError) %{comments: {:missing, nil}, title: {:missing, nil}}
    iex:10: Post.make!/2

iex> Post.make!(%{comments: %{}, title: :test})
** (Construct.MakeError) %{comments: {:invalid, %{}}, title: {:invalid, :test}}
    iex:10: Post.make!/2

iex> Post.make!(%{comments: [%{}], title: "what the title?"})
** (Construct.MakeError) %{comments: %{text: {:missing, [nil]}}}
    iex:10: Post.make!/2

Contributing
	Fork it
	Create your feature branch (git checkout -b my-new-feature)
	Commit your changes (git commit -am 'add some feature')
	Push to the branch (git push origin my-new-feature)
	Create new Pull Request

Construct internally divided into three components:
	Construct — defining structures;
	Construct.Cast — making structure instances;
	Construct.Type — type-coercion and custom type behaviour.

Construct definition
defmodule StructureName do
  use Construct, struct_opts

  structure do
    include AnotherStructure
    field name, type, options
  end
end
struct_opts is options passed to make/2 and make!/2, described in Construct.Cast.make/3.
When you type use Construct — library bootstrapped few functions with Construct behaviour:
	make/2 — just an alias to Construct.Cast.make/3;
	make!/2 — alias to make/2 but throws Construct.MakeError exception if provided params are invalid;
	cast/2 — alias to make/2 too, for follow Construct.Type behaviour and use defined structure as type.


      


      
        Summary


  
    Types
  


    
      
        t()

      


    





  
    Callbacks
  


    
      
        cast(params, opts)

      


        Alias to make/2, used to follow Construct.Type.cast/1 callback.



    


    
      
        make(params, opts)

      


        Alias to Construct.Cast.make/3.



    


    
      
        make!(params, opts)

      


        Alias to make/2, but raises an Construct.MakeError exception if params have errors.



    





  
    Functions
  


    
      
        construct?(module)

      


        Checks if provided module is Construct module



    


    
      
        field(name, type \\ :string, opts \\ [])

      


        Defines field on the structure with given name, type and options.



    


    
      
        include(module, opts \\ [])

      


        Includes provided structure and checks definition for validity at compile-time.



    


    
      
        structure(list)

      


        Defines a structure.



    


    
      
        structure_compile_hook(type, list)

      


        No doc at this time, should be written for 3.0.0 release



    


    
      
        types_of!(module)

      


        Collect types from defined Construct module to map

          @type t() :: struct()


      



  


        

      

      
        Callbacks


        


  
    
      
    
    
      cast(params, opts)



        
          
        

    

  


  

      

          @callback cast(params :: map(), opts :: Keyword.t()) :: {:ok, t()} | {:error, term()}


      


Alias to make/2, used to follow Construct.Type.cast/1 callback.
To use this structure as custom type.

  



  
    
      
    
    
      make(params, opts)



        
          
        

    

  


  

      

          @callback make(params :: map(), opts :: Keyword.t()) :: {:ok, t()} | {:error, term()}


      


Alias to Construct.Cast.make/3.

  



  
    
      
    
    
      make!(params, opts)



        
          
        

    

  


  

      

          @callback make!(params :: map(), opts :: Keyword.t()) :: t()


      


Alias to make/2, but raises an Construct.MakeError exception if params have errors.

  


        

      

      
        Functions

Checks if provided module is Construct module

  



    

    

  
    
      
    
    
      field(name, type \\ :string, opts \\ [])


        (macro)


        
          
        

    

  


  

      

          @spec field(atom(), Construct.Type.t(), Keyword.t()) :: Macro.t()


      


Defines field on the structure with given name, type and options.
Checks definition validity at compile time by name, type and options.
For custom types checks for module existence and Construct.Type.cast/1 callback.
If field definition is invalid for some reason — it throws an Construct.DefinitionError
exception with detailed reason.
Options
	:default — sets default value for that field:
	The default value is calculated at compilation time, so don't use expressions like
DateTime.utc_now or Ecto.UUID.generate as they would then be the same for all structures;

	Value from params is compared with default value before and after type cast;

	If you pass field :a, type, default: nil and make(%{a: nil}) — type coercion will
not be used, nil compares with default value and just appends that value to structure;

	If field doesn't exist in params, it will use default value.


By default this option is unset. Notice that you can't use functions as a default value.



  



    

  
    
      
    
    
      include(module, opts \\ [])


        (macro)


        
          
        

    

  


  

      

          @spec include(
  t(),
  keyword()
) :: Macro.t()


      


Includes provided structure and checks definition for validity at compile-time.
Options
	:only - (integer) specify fields that should be taken from included module,
throws an error when field doesn't exist in provided module.

If included structure is invalid for some reason — this macro throws an
Construct.DefinitionError exception with detailed reason.

  



  
    
      
    
    
      structure(list)


        (macro)


        
          
        

    

  


  

Defines a structure.

  



  
    
      
    
    
      structure_compile_hook(type, list)


        (macro)


        
          
        

    

  


  

No doc at this time, should be written for 3.0.0 release

  



  
    
      
    
    
      types_of!(module)



        
          
        

    

  


  

Collect types from defined Construct module to map

Module to make structure instance from provided params.
You can use it standalone, without defining structure, by providing types and params to make/3.

        types()

      


    





  
    Functions
  


    
      
        make(struct_or_types, params, opts \\ [])

      


        Function to compose structure instance from params

          @type options() :: [{:error_values, boolean()}]

          @type type() :: {Construct.Type.t(), Keyword.t()}

          @type types() :: %{required(atom()) => type()}


      



  


        

      

      
        Functions


        


    

  
    
      
    
    
      make(struct_or_types, params, opts \\ [])



        
          
        

    

  


  

      

          @spec make(atom() | types(), map(), options()) ::
  {:ok, Construct.t() | map()} | {:error, term()}


      


Function to compose structure instance from params:
defmodule User do
  use Construct

  structure do
    field :name
  end
end

iex> make(User, %{name: "john doe"})
{:ok, %User{name: "john doe"}}

iex> make(User, name: "john doe")
{:ok, %User{name: "john doe"}}
Also you can use it as standalone complex type-coercion by providing types and params:
iex> make(%{name: {:string, []}}, %{"name" => "john doe"})
{:ok, %{name: "john doe"}}

iex> make(%{name: :string}, %{"name" => "john doe"})
{:ok, %{name: "john doe"}}

iex> make([name: :string], %{"name" => "john doe"})
{:ok, %{name: "john doe"}}

iex> make(%{age: {:integer, [default: 18]}}, %{"age" => "42"})
{:ok, %{age: 42}}

iex> make(%{age: {:integer, [default: 18]}}, %{})
{:ok, %{age: 18}}

iex> types = %{title: {:string, []}, comments: {{:array, :string}, default: []}}
iex> make(types, %{title: "article", comments: ["awesome", "great!", "whoa!"]})
{:ok, %{title: "article", comments: ["awesome", "great!", "whoa!"]}}

iex> make(%{user: %{name: :string, age: {:integer, default: 21}}}, %{"user" => %{"name" => "john"}})
{:ok, %{user: %{name: "john", age: 21}}}

Type-coercion module, originally copied and modified from
Ecto.Type
and behaviour to implement your own types.
Defining custom types
defmodule CustomType do
  @behaviour Construct.Type

  def cast(value) do
    {:ok, value}
  end
end

        builtin()

      


    


    
      
        cast_ret()

      


    


    
      
        custom()

      


    


    
      
        t()

      


    





  
    Callbacks
  


    
      
        cast(term)

      


        Casts the given input to the custom type.



    





  
    Functions
  


    
      
        builtin()

      


    


    
      
        builtinc()

      


    


    
      
        cast(type, term)

      


        Behaves like cast/3, but without options provided to nested types.



    


    
      
        cast(type, term, opts)

      


        Casts a value to the given type.



    


    
      
        primitive?(type)

      


        Checks if we have a primitive type.

          @type builtin() ::
  :integer
  | :float
  | :boolean
  | :string
  | :binary
  | :pid
  | :reference
  | :decimal
  | :utc_datetime
  | :naive_datetime
  | :date
  | :time
  | :any
  | :array
  | {:array, t()}
  | :map
  | {:map, t()}
  | :struct

          @type cast_ret() :: {:ok, term()} | {:error, term()} | :error


      



  



  
    
      
    
    
      custom()



        
          
        

    

  


  

      

          @type custom() :: module() | Construct.t()

          @type t() :: builtin() | custom() | [builtin() | custom()]

          @callback cast(term()) :: cast_ret()


      


Casts the given input to the custom type.

          @spec cast(t(), term()) :: cast_ret() | any()


      


Behaves like cast/3, but without options provided to nested types.

  



  
    
      
    
    
      cast(type, term, opts)



        
          
        

    

  


  

      

          @spec cast(t(), term(), options) :: cast_ret() | any() when options: Keyword.t()


      


Casts a value to the given type.
iex> cast(:any, "whatever")
{:ok, "whatever"}

iex> cast(:any, nil)
{:ok, nil}
iex> cast(:string, nil)
:error

iex> cast(:integer, 1)
{:ok, 1}
iex> cast(:integer, "1")
{:ok, 1}
iex> cast(:integer, "1.0")
:error

iex> cast(:float, 1.0)
{:ok, 1.0}
iex> cast(:float, 1)
{:ok, 1.0}
iex> cast(:float, "1")
{:ok, 1.0}
iex> cast(:float, "1.0")
{:ok, 1.0}
iex> cast(:float, "1-foo")
:error

iex> cast(:boolean, true)
{:ok, true}
iex> cast(:boolean, false)
{:ok, false}
iex> cast(:boolean, "1")
{:ok, true}
iex> cast(:boolean, "0")
{:ok, false}
iex> cast(:boolean, "whatever")
:error

iex> cast(:string, "beef")
{:ok, "beef"}
iex> cast(:binary, "beef")
{:ok, "beef"}

iex> cast(:decimal, Decimal.from_float(1.0))
{:ok, Decimal.from_float(1.0)}
iex> cast(:decimal, Decimal.new("1.0"))
{:ok, Decimal.from_float(1.0)}
iex> cast(:decimal, 1.0)
{:ok, Decimal.from_float(1.0)}
iex> cast(:decimal, "1.0")
{:ok, Decimal.from_float(1.0)}

iex> cast({:array, :integer}, [1, 2, 3])
{:ok, [1, 2, 3]}
iex> cast({:array, :integer}, ["1", "2", "3"])
{:ok, [1, 2, 3]}
iex> cast({:array, :string}, [1, 2, 3])
:error
iex> cast(:string, [1, 2, 3])
:error

iex> cast({Construct.Types.Enum, [:a, :b, :c]}, :a)
{:ok, :a}
iex> cast({Construct.Types.Enum, [:a, :b, :c]}, :d)
{:error, passed_value: :d, valid_values: [:a, :b, :c]}

          @spec primitive?(t()) :: boolean()


      


Checks if we have a primitive type.
iex> primitive?(:string)
true
iex> primitive?(Another)
false

iex> primitive?({:array, :string})
true
iex> primitive?({:array, Another})
true

iex> primitive?([Another, {:array, :integer}])
false

Provides a way to create parametrized types.
See Construct.Types.Enum implementation for more information.

          @callback castc(term(), arg :: term()) :: Construct.Type.cast_ret()

Extracts list of separated by comma values from string.
You can use it alone, just for splitting values:
defmodule Structure do
  use Construct do
    field :values, Construct.Types.CommaList
  end
end

iex> Structure.make!(values: "foo,bar,baz,42")
%Structure{values: ["foo", "bar", "baz", "42"]}

iex> Structure.make!(values: ["foo", 42])
%Structure{values: ["foo", 42]}
Also you can compose it with other types:
defmodule UserInfoRequest do
  use Construct do
    field :user_ids, [Construct.Types.CommaList, {:array, :integer}]
  end
end

iex> UserInfoRequest.make!(%{user_ids: "1,2,42"})
%UserInfoRequest{user_ids: [1, 2, 42]}

iex> UserInfoRequest.make(%{user_ids: "1,foo"})
{:error, %{user_ids: :invalid}}

Implements an abstract enum type.
Usage
defmodule MyApp.Order do
  use Construct do
    field :type, {Construct.Types.Enum, [:delivery, :pickup]}
  end
end
Then you can validate that :type field accepts only specified
values.
iex> MyApp.Order.make(%{type: :delivery})
{:ok, %MyApp.Order{type: :delivery}}
iex> MyApp.Order.make(%{type: :other})
{:error, %{type: passed_value: :other, valid_values: [:delivery, :pickup]}}

Checks that provided binary is UUID-like string:
defmodule Structure do
  use Construct do
    field :value, Construct.Types.UUID
  end
end

iex> Structure.make!(value: "fd4ddf80-a7d9-4af8-b46c-26fc4566d92c")
%Structure{value: "fd4ddf80-a7d9-4af8-b46c-26fc4566d92c"}

iex> Structure.make(value: "invalid")
{:error, %{value: :invalid}}

